Cara Setting Load Balancing 2 ISP Dengan PCC MikroTik

chmood



Cara Setting load balancing 2 isp mikrotik dengan PCC mikrotik. Tujuannya mendistribusikan trafik dari user ke 2 wan atau 2 isp secara merata. Bukannya untuk menjadikan kapasitas bandwidth menjadi 2x lipat tapi berfungsi membagi beban koneksi kepada kedua isp tersebut agar seimbang.

Kondisi yang perlu disiapkan untuk setting load balancing 2 isp dengan pcc mikrotik :
  • Berlangganan internet 2 koneksi ISP / WAN
  • Mikrotik dengan minimal 3 Ethernet/port
  • PC User

Contoh Kasus :
Anggap Anda mempunyai / berlangganan 2 paket internet, misalnya berlangganan 2 telkom speedy dalam 1 lokasi, dan mempunyai konfigurasi IP Address seperti :
Modem Speedy 1
IP Address 192.168.0.1
Netmask 255.255.255.0

Modem Speedy 2
IP Address 192.168.1.1
Netmask 255.255.255.0

Dan rencananya ingin kedua koneksi internet speedy tersebut dapat terpakai keduanya untuk kebutuhan koneksi internet PC user dalam jaringan lokal Anda.

Yang pertama, kita koneksikan mikrotik kita dengan modem, dengan menambahkan IP Address pada masing-masing interfaces WAN/internet.

Contoh susunan port/interfaces pada mikrotik :

Modem Speedy 1 : ether1-inet1
Modem Speedy 2 : ether2-inet2
LAN : ether3-lan

Tambahkan IP Address pada masing-masing interface :

/ ip address
add address=192.168.0.2/24 interface=ether1-inet1 network=192.168.0.0 disable=no
add address=192.168.1.2/24 interface=ether2-inet2 network=192.168.1.0 disable=no
add address=192.168.2.1/24 interface=ether3-lan network=192.168.2.0 disable=no

 
Periksa koneksi dari mikrotik ke masing-masing modem speedy. Pastikan terhubung dengan baik.

Mangle Load Balancing Dengan PCC MikroTik 

PCC (Per Connection Classifier) dapat mengelompokan koneksi yang keluar masuk mikrotik menjadi beberapa bagian. Kelebihan lain menggunakan PCC adalah router dapat mengingat jalur gateway setiap koneksi berkaitan yang keluar masuk agar melewati jalur gateway yang sama untuk menghindari sering putusnya koneksi karena perpindahan gateway.

Di bagian ini kita akan membagi dan menandai beban trafik dari PC user menjadi 2 bagian. 1 bagian melewati gateway modem speedy 1, dan 1 bagian lagi melewati gateway modem speedy 2.

/ip firewall mangle
add action=mark-connection chain=input comment="" connection-state=new \
    disabled=no in-interface=ether1-inet1 new-connection-mark=isp-1 passthrough=yes
add action=mark-connection chain=input comment="" connection-state=new \
    disabled=no in-interface=ether2-inet2 new-connection-mark=isp-2 passthrough=yes
 
add action=mark-routing chain=output comment="" connection-mark=isp-1 \
    disabled=no new-routing-mark=jalur-1 passthrough=no
add action=mark-routing chain=output comment="" connection-mark=isp-2 \
    disabled=no new-routing-mark=jalur-2 passthrough=no
 
add action=mark-connection chain=prerouting comment="" disabled=no \
    dst-address-type=!local in-interface=ether3-lan new-connection-mark=\
    isp-1 passthrough=yes per-connection-classifier=both-addresses-and-ports:2/0
add action=mark-connection chain=prerouting comment="" disabled=no \
    dst-address-type=!local in-interface=ether3-lan new-connection-mark=\
    isp-2 passthrough=yes per-connection-classifier=both-addresses-and-ports:2/1
 
add action=mark-routing chain=prerouting comment="" connection-mark=isp-1 \
    disabled=no in-interface=ether3-lan new-routing-mark=jalur-1 passthrough=yes
add action=mark-routing chain=prerouting comment="" connection-mark=isp-2 \
    disabled=no in-interface=ether3-lan new-routing-mark=jalur-2 passthrough=yes


NAT Load Balancing Dengan PCC MikroTik 

Set default NAT masquerade ke masing-masing interface WAN modem speedy

/ip firewall nat 
add chain=srcnat action=masquerade out-interface=ether1-inet1 comment="" disabled=no 
add chain=srcnat action=masquerade out-interface=ether2-inet2 comment="" disabled=no


Routing Load Balancing Dengan PCC MikroTik 

Kemudian kita arahkan kelompok trafik user yang sudah dikelompokan menjadi beberapa bagian ke arah masing-masing jalur gateway internet Anda. 

/ip route 
## Distribusi koneksi internet ke Modem Speedy 1
add disabled=no distance=1 dst-address=0.0.0.0/0 gateway=192.168.0.1 \
    routing-mark=jalur-1 
 
## Distribusi koneksi internet ke Modem Speedy 2
add disabled=no distance=2 dst-address=0.0.0.0/0 gateway=192.168.1.1 \
    routing-mark=jalur-2
 
add comment="" disabled=no distance=1 dst-address=0.0.0.0/0 gateway=192.168.0.1
add comment="" disabled=no distance=2 dst-address=0.0.0.0/0 gateway=192.168.1.1


Dan akhirnya tahap pengujian setting load balancing 2 isp dengan PCC mikrotik. Anda bisa melihat statistik pada masing-masing interfaces WAN/internet mikrotik Anda jika anda melakukan aktifitas browsing dari PC client untuk melihat load balancing 2 isp ini bekerja.
Untuk di ketahui load balancing pake teknik pcc ini jalan efektif dan mendekati seimbang jika semakin banyak koneksi dari client. Dan lebih manteb pakai ISP yg mempunyai bandwidth FIX (dedicated) bukan yg up to.


Category
Komentar